host := "bl@flo-homeserver"
hagfisk_dir := "~/hagfisk"

# Build binary locally
build:
    echo "Building hagfisk binary..."
    cargo build --release

# Sync binary to server
deploy: build
    ssh -q {{host}} "rm -f {{hagfisk_dir}}/hagfisk"
    echo "Syncing binary to remote..."
    rsync -avz --progress ./target/release/hagfisk {{host}}:{{hagfisk_dir}}/hagfisk
    echo "Restoring SELinux contexts..."
    ssh -t -q {{host}} "sudo restorecon -RF {{hagfisk_dir}}"
    ssh -q {{host}} "systemctl --user daemon-reload"
    ssh -q {{host}} "systemctl --user restart hagfisk.service"

# Enable and start service
enable-now-app:
    ssh {{host}} "systemctl --user enable --now hagfisk.service"

# Start service on remote
start-app:
    ssh {{host}} "systemctl --user start hagfisk.service"

# Stop service on remote
stop-app:
    ssh {{host}} "systemctl --user stop hagfisk.service"

# Restart service on remote
restart-app:
    ssh {{host}} "systemctl --user restart hagfisk.service"

# Stream logs from remote
logs-app:
    ssh {{host}} "journalctl --user -u hagfisk -f"

# Show status of hagfisk
ps-app:
    ssh {{host}} "systemctl --user status hagfisk.service"

# Enable and start ingest service and timer
enable-now-ingest:
    ssh {{host}} "systemctl --user enable --now hagfisk-ingest.service hagfisk-ingest.timer"

# Start ingest on remote
start-ingest:
    ssh {{host}} "systemctl --user start hagfisk-ingest.service hagfisk-ingest.timer"

# Stop ingest on remote
stop-ingest:
    ssh {{host}} "systemctl --user stop hagfisk-ingest.service hagfisk-ingest.timer"

# Restart ingest on remote
restart-ingest:
    ssh {{host}} "systemctl --user restart hagfisk-ingest.service hagfisk-ingest.timer"

# Stream ingest logs from remote
logs-ingest:
    ssh {{host}} "journalctl --user -u hagfisk-ingest -f"

# Show status of hagfisk ingest
ps-ingest:
    ssh {{host}} "systemctl --user status hagfisk-ingest.service"